mirror of https://github.com/jorgebucaran/fisher
Compare commits
125 Commits
Author | SHA1 | Date |
---|---|---|
Jorge Bucaran | 1f0dc2b497 | 3 weeks ago |
Jorge Bucaran | a6bf0e5b9e | 3 weeks ago |
mattmc3 | 63c18183b7 | 3 weeks ago |
Jorge Bucaran | 2efd33ccd0 | 1 year ago |
Vasyl Zuziak | 4c95fd94c6 | 1 year ago |
Razvan Azamfirei | 59228d6215 | 1 year ago |
Jorge Bucaran | ed7c28ea78 | 1 year ago |
Jorge Bucaran | dc543b2a65 | 1 year ago |
Jorge Bucaran | 2440ef4ebd | 1 year ago |
Jorge Bucaran | 67bec738db | 2 years ago |
James Hillyerd | 5841ec0091 | 2 years ago |
Zhizhen He | 4cd902e63f | 2 years ago |
Jorge Bucaran | 4199657495 | 2 years ago |
mattmc3 | 2e8a24614b | 2 years ago |
Jorge Bucaran | 36810b3940 | 2 years ago |
Tim | 53c06c9d2f | 2 years ago |
Jorge Bucaran | d431f45abc | 2 years ago |
Jorge Bucaran | c05a169187 | 2 years ago |
Jorge Bucaran | 67a543ef60 | 2 years ago |
Jorge Bucaran | d92d62457f | 2 years ago |
Patrick | 626afefcb0 | 2 years ago |
Jorge Bucaran | 2ef758ec27 | 2 years ago |
Jorge Bucaran | de3eee489f | 2 years ago |
Jorge Bucaran | 3ae4b29137 | 2 years ago |
Jorge Bucaran | 7c4024da66 | 2 years ago |
Jorge Bucaran | 357d682b10 | 2 years ago |
Jorge Bucaran | 1662b799eb | 2 years ago |
Jorge Bucaran | 604f8ff1ea | 2 years ago |
Jorge Bucaran | 475505312c | 2 years ago |
Jorge Bucaran | daddbadb79 | 2 years ago |
Jorge Bucaran | bad0471c4b | 2 years ago |
Jorge Bucaran | 79b1cf17ca | 2 years ago |
Austin Ziegler | 01af91773f | 2 years ago |
Jorge Bucaran | 7fdb083c60 | 2 years ago |
Jorge Bucaran | 36c1930aa7 | 2 years ago |
Jorge Bucaran | 507c9cc425 | 2 years ago |
Jorge Bucaran | 5622dd660f | 2 years ago |
Jorge Bucaran | cf4c6cc561 | 2 years ago |
Ilan Cosman | b3c5336480 | 2 years ago |
Jorge Bucaran | a4e74bd6f1 | 2 years ago |
eitsupi | 164628b696 | 2 years ago |
Yohan Min | 74dabc5d5a | 2 years ago |
Bugakov Mikhail | 354c8fccec | 2 years ago |
anakimluke | 0a0c48993a | 3 years ago |
Jorge Bucaran | 93dafd242b | 3 years ago |
Jorge Bucaran | 1f080b0457 | 3 years ago |
Jason Nader | 885129b7d3 | 3 years ago |
Jorge Bucaran | b2c317a2ae | 3 years ago |
Jorge Bucaran | dc7ada7a78 | 3 years ago |
Jorge Bucaran | c220662604 | 3 years ago |
Jorge Bucaran | 7bd5bfcac1 | 3 years ago |
Jorge Bucaran | 28bb0e172c | 3 years ago |
Bruce D'Arcus | b9b1eda07a | 3 years ago |
Jorge Bucaran | 247b58e0d9 | 4 years ago |
Jorge Bucaran | e7a538239b | 4 years ago |
Jag Talon | b222175fc8 | 4 years ago |
Jorge Bucaran | 48c414fa09 | 4 years ago |
Jorge Bucaran | 00f130ed90 | 4 years ago |
Daniël Franke | a0a68de919 | 4 years ago |
Daniël Franke | 6cc13ada7e | 4 years ago |
Daniël Franke | 8ae139dc9e | 4 years ago |
Jorge Bucaran | 56c629a3a9 | 4 years ago |
Jorge Bucaran | 3f0851c5cb | 4 years ago |
Jorge Bucaran | 94e934d49e | 4 years ago |
Jorge Bucaran | 746ec1a504 | 4 years ago |
Jorge Bucaran | 3e7c4015ab | 4 years ago |
Jorge Bucaran | a8a8a96287 | 4 years ago |
Jorge Bucaran | 32ed213b4a | 4 years ago |
Jorge Bucaran | 0b8daa2b8f | 4 years ago |
Jorge Bucaran | 9cc7d9582f | 4 years ago |
Jorge Bucaran | d0c3d1840a | 4 years ago |
Jorge Bucaran | f4739a8c7d | 4 years ago |
Jorge Bucaran | 57ed19f945 | 4 years ago |
Jorge Bucaran | 7ed1de7e56 | 4 years ago |
Jorge Bucaran | 3e5b263785 | 4 years ago |
Jorge Bucaran | b9f222c52e | 4 years ago |
Jorge Bucaran | 70c9a59b53 | 4 years ago |
Jorge Bucaran | 09fc107734 | 4 years ago |
Jorge Bucaran | 48a61924ad | 4 years ago |
Jorge Bucaran | a2e3d5463f | 4 years ago |
Jorge Bucaran | 8f84ee6144 | 4 years ago |
Jorge Bucaran | b2501f620d | 4 years ago |
Jorge Bucaran | d1a9ae0f7f | 4 years ago |
Jorge Bucaran | c8091b3dee | 4 years ago |
Jorge Bucaran | 7a47e294b9 | 4 years ago |
Jorge Bucaran | aa4e1caca5 | 4 years ago |
Jorge Bucaran | 0e2227019e | 4 years ago |
Jorge Bucaran | 8fde904564 | 4 years ago |
Jorge Bucaran | da228c9f70 | 4 years ago |
Jorge Bucaran | c3659bed01 | 4 years ago |
Jorge Bucaran | 3edac36e38 | 4 years ago |
Jorge Bucaran | 72a40f13ce | 4 years ago |
Jorge Bucaran | fbc117df2d | 4 years ago |
Jorge Bucaran | 6dc9e1237d | 4 years ago |
Jorge Bucaran | b5650d3ef6 | 4 years ago |
Jorge Bucaran | fca10da157 | 4 years ago |
Jorge Bucaran | f24bb10edb | 4 years ago |
Jorge Bucaran | c9decadc16 | 4 years ago |
Jorge Bucaran | 7d6bd9f9b3 | 4 years ago |
Jorge Bucaran | ed32770424 | 4 years ago |
Jorge Bucaran | f5b6254833 | 4 years ago |
Jorge Bucaran | b4c2fcc68a | 4 years ago |
jorgebucaran | ae423be725 | 4 years ago |
jorgebucaran | 285fc352b7 | 4 years ago |
jorgebucaran | f6f2b5d149 | 4 years ago |
jorgebucaran | 1644724ef1 | 4 years ago |
jorgebucaran | 721ac3f707 | 4 years ago |
Jorge Bucaran | fb16985935 | 4 years ago |
Jorge Bucaran | db6801f565 | 4 years ago |
Jorge Bucaran | 6b1a886c58 | 4 years ago |
Jorge Bucaran | d0c30d9723 | 4 years ago |
rany | cd9d69209e | 4 years ago |
Jorge Bucaran | 4ff6128860 | 4 years ago |
Jorge Bucaran | 2bbc06a965 | 4 years ago |
Jorge Bucaran | eab5c67f0b | 4 years ago |
Jorge Bucaran | 861cd38133 | 4 years ago |
Jorge Bucaran | cc06470da1 | 4 years ago |
Jorge Bucaran | f4b32b3419 | 4 years ago |
Jorge Bucaran | dc63a83c78 | 4 years ago |
Jorge Bucaran | f26e1d121f | 4 years ago |
Jorge Bucaran | 5368e72863 | 4 years ago |
Jorge Bucaran | f091c22c60 | 4 years ago |
Jorge Bucaran | f7c347b5d0 | 4 years ago |
Jorge Bucaran | 3f8552e200 | 4 years ago |
Jorge Bucaran | ac1b49b43b | 4 years ago |
@ -1,7 +1,7 @@
|
||||
complete -c fisher -x -l help -d "print usage help"
|
||||
complete -c fisher -x -l version -d "print fisher version"
|
||||
complete -c fisher -x -n "__fish_use_subcommand" -a install -d "install plugins"
|
||||
complete -c fisher -x -n "__fish_use_subcommand" -a update -d "update installed plugins"
|
||||
complete -c fisher -x -n "__fish_use_subcommand" -a remove -d "remove installed plugins"
|
||||
complete -c fisher -x -n "__fish_use_subcommand" -a list -d "list installed plugins matching <regex>"
|
||||
complete -c fisher -x -n "__fish_seen_subcommand_from update remove" -a "(fisher list)"
|
||||
complete --command fisher --exclusive --long help --description "Print help"
|
||||
complete --command fisher --exclusive --long version --description "Print version"
|
||||
complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
|
||||
complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
|
||||
complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
|
||||
complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
|
||||
complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"
|
||||
|
@ -1,204 +0,0 @@
|
||||
set -g fisher_version 4.1.0
|
||||
|
||||
function fisher -a cmd -d "fish plugin manager"
|
||||
set -q fisher_path || set -l fisher_path $__fish_config_dir
|
||||
set -l fish_plugins $__fish_config_dir/fish_plugins
|
||||
|
||||
switch "$cmd"
|
||||
case -v --version
|
||||
echo "fisher, version $fisher_version"
|
||||
case "" -h --help
|
||||
echo "usage: fisher install <plugins...> install plugins"
|
||||
echo " fisher remove <plugins...> remove installed plugins"
|
||||
echo " fisher update <plugins...> update installed plugins"
|
||||
echo " fisher update update all installed plugins"
|
||||
echo " fisher list [<regex>] list installed plugins matching regex"
|
||||
echo "options:"
|
||||
echo " -v or --version print fisher version"
|
||||
echo " -h or --help print this help message"
|
||||
case ls list
|
||||
string match --entire --regex -- "$argv[2]" $_fisher_plugins
|
||||
case install update remove rm
|
||||
isatty || read -laz stdin && set argv $argv[2..-1] $stdin
|
||||
set -l install_plugins
|
||||
set -l update_plugins
|
||||
set -l remove_plugins
|
||||
set -l arg_plugins $argv
|
||||
set -l old_plugins $_fisher_plugins
|
||||
set -l new_plugins
|
||||
|
||||
if test -z "$argv[1]"
|
||||
if test "$cmd" != update || test ! -e $fish_plugins
|
||||
echo "fisher: not enough arguments for command: \"$cmd\"" >&2 && return 1
|
||||
end
|
||||
set arg_plugins (string trim <$fish_plugins)
|
||||
end
|
||||
|
||||
for plugin in $arg_plugins
|
||||
test -e "$plugin" && set plugin (realpath $plugin)
|
||||
contains -- "$plugin" $new_plugins || set -a new_plugins $plugin
|
||||
end
|
||||
|
||||
if set -q argv[1]
|
||||
for plugin in $new_plugins
|
||||
if contains -- "$plugin" $old_plugins
|
||||
if test "$cmd" = install || test "$cmd" = update
|
||||
set -a update_plugins $plugin
|
||||
else
|
||||
set -a remove_plugins $plugin
|
||||
end
|
||||
else if test "$cmd" != install
|
||||
echo "fisher: plugin not installed: \"$plugin\"" >&2 && return 1
|
||||
else
|
||||
set -a install_plugins $plugin
|
||||
end
|
||||
end
|
||||
else
|
||||
for plugin in $new_plugins
|
||||
if contains -- "$plugin" $old_plugins
|
||||
set -a update_plugins $plugin
|
||||
else
|
||||
set -a install_plugins $plugin
|
||||
end
|
||||
end
|
||||
|
||||
for plugin in $old_plugins
|
||||
if not contains -- "$plugin" $new_plugins
|
||||
set -a remove_plugins $plugin
|
||||
end
|
||||
end
|
||||
end
|
||||
|
||||
set -l pid_list
|
||||
set -l source_plugins
|
||||
set -l fetch_plugins $update_plugins $install_plugins
|
||||
|
||||
for plugin in $fetch_plugins
|
||||
set -l source (command mktemp -d)
|
||||
set -a source_plugins $source
|
||||
|
||||
command mkdir -p $source/{completions,conf.d,functions}
|
||||
|
||||
fish -c "
|
||||
if test -e $plugin
|
||||
command cp -Rf $plugin/* $source
|
||||
else
|
||||
set temp (command mktemp -d)
|
||||
set name (string split \@ $plugin) || set name[2] HEAD
|
||||
set url https://codeload.github.com/\$name[1]/tar.gz/\$name[2]
|
||||
set -q fisher_user_api_token && set opts -u $fisher_user_api_token
|
||||
|
||||
echo fetching \$url >&2
|
||||
if command curl $opts -Ss -w \"\" \$url 2>&1 | command tar -xzf- -C \$temp 2>/dev/null
|
||||
command cp -Rf \$temp/*/* $source
|
||||
else
|
||||
echo fisher: invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
|
||||
command rm -rf $source
|
||||
end
|
||||
command rm -rf \$temp
|
||||
end
|
||||
|
||||
test ! -e $source && exit
|
||||
command mv -f (string match --entire --regex -- \.fish\\\$ $source/*) $source/functions 2>/dev/null" &
|
||||
|
||||
set -a pid_list $last_pid
|
||||
end
|
||||
|
||||
wait $pid_list 2>/dev/null
|
||||
|
||||
for plugin in $fetch_plugins
|
||||
if set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
|
||||
if set -l index (contains --index -- "$plugin" $install_plugins)
|
||||
set -e install_plugins[$index]
|
||||
else
|
||||
set -e update_plugins[(contains --index -- "$plugin" $update_plugins)]
|
||||
end
|
||||
end
|
||||
end
|
||||
|
||||
for plugin in $update_plugins $remove_plugins
|
||||
if set --erase _fisher_plugins[(contains --index -- $plugin $_fisher_plugins)] 2>/dev/null
|
||||
set -l plugin_files_var _fisher_(string escape --style=var $plugin)_files
|
||||
|
||||
if contains -- "$plugin" $remove_plugins
|
||||
for file in (string match --entire --regex -- "conf\.d/" $$plugin_files_var)
|
||||
emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_uninstall
|
||||
end
|
||||
echo -s (set_color --bold)"removing $plugin"(set_color normal) \n-$$plugin_files_var >&2
|
||||
end
|
||||
|
||||
command rm -rf $$plugin_files_var
|
||||
functions --erase (string match --entire --regex -- "functions/" $$plugin_files_var \
|
||||
| string replace --all --regex -- '^.*/|\.fish$' "")
|
||||
set --erase $plugin_files_var
|
||||
end
|
||||
end
|
||||
|
||||
for plugin in $update_plugins $install_plugins
|
||||
set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
|
||||
|
||||
command cp -Rf $source/{functions,conf.d,completions} $fisher_path
|
||||
|
||||
set -l files (string replace $source $fisher_path $source/{functions,conf.d,completions}/*)
|
||||
set -U _fisher_(string escape --style=var $plugin)_files $files
|
||||
|
||||
contains -- $plugin $_fisher_plugins || set -Ua _fisher_plugins $plugin
|
||||
contains -- $plugin $install_plugins && set -l event "install" || set -l event "update"
|
||||
|
||||
echo -s (set_color --bold)"installing $plugin"(set_color normal) \n+$files >&2
|
||||
|
||||
for file in (string match --entire --regex -- "[functions/|conf\.d/].*fish\$" $files)
|
||||
source $file
|
||||
if string match --quiet --regex -- "conf\.d/" $file
|
||||
emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_$event
|
||||
end
|
||||
end
|
||||
end
|
||||
|
||||
command rm -rf $source_plugins
|
||||
functions -q fish_prompt || source $__fish_data_dir/functions/fish_prompt.fish
|
||||
|
||||
set -q _fisher_plugins[1] || set -e _fisher_plugins
|
||||
set -q _fisher_plugins && printf "%s\n" $_fisher_plugins >$fish_plugins || command rm -f $fish_plugins
|
||||
|
||||
set -l total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
|
||||
test "$total" != "0 0 0" && echo (string join ", " (
|
||||
test $total[1] = 0 || echo "$total[1] installed") (
|
||||
test $total[2] = 0 || echo "$total[2] updated") (
|
||||
test $total[3] = 0 || echo "$total[3] removed")
|
||||
) "plugin/s" >&2
|
||||
case \*
|
||||
echo "fisher: unknown flag or command: \"$cmd\" (see `fisher -h`)" >&2 && return 1
|
||||
end
|
||||
end
|
||||
|
||||
## Migrations ##
|
||||
set -q XDG_DATA_HOME || set -l XDG_DATA_HOME ~/.local/share
|
||||
test -e $XDG_DATA_HOME/fisher && command rm -rf $XDG_DATA_HOME/fisher
|
||||
if functions -q _fisher_self_update || test -e $__fish_config_dir/fishfile
|
||||
function _fisher_migrate
|
||||
function _fisher_complete
|
||||
if not _fisher_list | string match --entire --regex --quiet -- jorgebucaran/fisher
|
||||
fisher install jorgebucaran/fisher 2>/dev/null
|
||||
end
|
||||
functions --erase _fisher_complete
|
||||
end
|
||||
set -q XDG_DATA_HOME || set XDG_DATA_HOME ~/.local/share
|
||||
set -q XDG_CACHE_HOME || set XDG_CACHE_HOME ~/.cache
|
||||
set -q XDG_CONFIG_HOME || set XDG_CONFIG_HOME ~/.config
|
||||
set -q fisher_path || set fisher_path $__fish_config_dir
|
||||
|
||||
if test -e $__fish_config_dir/fishfile
|
||||
command awk '/#|^gitlab|^ *$/ { next } $0' <$__fish_config_dir/fishfile >>$__fish_config_dir/fish_plugins
|
||||
end
|
||||
|
||||
command rm -rf $__fish_config_dir/fishfile $fisher_path/{conf.d,completions}/fisher.fish {$XDG_DATA_HOME,$XDG_CACHE_HOME,$XDG_CONFIG_HOME}/fisher
|
||||
functions --erase _fisher_migrate _fisher_copy_user_key_bindings _fisher_ls _fisher_fmt _fisher_self_update _fisher_self_uninstall _fisher_commit _fisher_parse _fisher_fetch _fisher_add _fisher_rm _fisher_jobs _fisher_now _fisher_help
|
||||
|
||||
fisher update
|
||||
end
|
||||
|
||||
echo "bootstrapping fisher $fisher_version for the first time, learn more at "(set_color --bold --underline)"https://git.io/fisher-4"(set_color normal) >&2
|
||||
|
||||
_fisher_migrate
|
||||
end
|
@ -0,0 +1,240 @@
|
||||
function fisher --argument-names cmd --description "A plugin manager for Fish"
|
||||
set --query fisher_path || set --local fisher_path $__fish_config_dir
|
||||
set --local fisher_version 4.4.5
|
||||
set --local fish_plugins $__fish_config_dir/fish_plugins
|
||||
|
||||
switch "$cmd"
|
||||
case -v --version
|
||||
echo "fisher, version $fisher_version"
|
||||
case "" -h --help
|
||||
echo "Usage: fisher install <plugins...> Install plugins"
|
||||
echo " fisher remove <plugins...> Remove installed plugins"
|
||||
echo " fisher update <plugins...> Update installed plugins"
|
||||
echo " fisher update Update all installed plugins"
|
||||
echo " fisher list [<regex>] List installed plugins matching regex"
|
||||
echo "Options:"
|
||||
echo " -v, --version Print version"
|
||||
echo " -h, --help Print this help message"
|
||||
echo "Variables:"
|
||||
echo " \$fisher_path Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
|
||||
case ls list
|
||||
string match --entire --regex -- "$argv[2]" $_fisher_plugins
|
||||
case install update remove
|
||||
isatty || read --local --null --array stdin && set --append argv $stdin
|
||||
|
||||
set --local install_plugins
|
||||
set --local update_plugins
|
||||
set --local remove_plugins
|
||||
set --local arg_plugins $argv[2..-1]
|
||||
set --local old_plugins $_fisher_plugins
|
||||
set --local new_plugins
|
||||
|
||||
test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins | string replace -- \~ ~)
|
||||
|
||||
if ! set --query argv[2]
|
||||
if test "$cmd" != update
|
||||
echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
|
||||
else if ! set --query file_plugins
|
||||
echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
|
||||
end
|
||||
set arg_plugins $file_plugins
|
||||
end
|
||||
|
||||
for plugin in $arg_plugins
|
||||
set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
|
||||
contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
|
||||
end
|
||||
|
||||
if set --query argv[2]
|
||||
for plugin in $new_plugins
|
||||
if contains -- "$plugin" $old_plugins
|
||||
test "$cmd" = remove &&
|
||||
set --append remove_plugins $plugin ||
|
||||
set --append update_plugins $plugin
|
||||
else if test "$cmd" = install
|
||||
set --append install_plugins $plugin
|
||||
else
|
||||
echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
|
||||
end
|
||||
end
|
||||
else
|
||||
for plugin in $new_plugins
|
||||
contains -- "$plugin" $old_plugins &&
|
||||
set --append update_plugins $plugin ||
|
||||
set --append install_plugins $plugin
|
||||
end
|
||||
|
||||
for plugin in $old_plugins
|
||||
contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
|
||||
end
|
||||
end
|
||||
|
||||
set --local pid_list
|
||||
set --local source_plugins
|
||||
set --local fetch_plugins $update_plugins $install_plugins
|
||||
set --local fish_path (status fish-path)
|
||||
|
||||
echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
|
||||
|
||||
for plugin in $fetch_plugins
|
||||
set --local source (command mktemp -d)
|
||||
set --append source_plugins $source
|
||||
|
||||
command mkdir -p $source/{completions,conf.d,themes,functions}
|
||||
|
||||
$fish_path --command "
|
||||
if test -e $plugin
|
||||
command cp -Rf $plugin/* $source
|
||||
else
|
||||
set temp (command mktemp -d)
|
||||
set repo (string split -- \@ $plugin) || set repo[2] HEAD
|
||||
|
||||
if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
|
||||
set name (string split -- / \$path)[-1]
|
||||
set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
|
||||
else
|
||||
set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
|
||||
end
|
||||
|
||||
echo Fetching (set_color --underline)\$url(set_color normal)
|
||||
|
||||
if command curl -q --silent -L \$url | command tar -xzC \$temp -f - 2>/dev/null
|
||||
command cp -Rf \$temp/*/* $source
|
||||
else
|
||||
echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
|
||||
command rm -rf $source
|
||||
end
|
||||
|
||||
command rm -rf \$temp
|
||||
end
|
||||
|
||||
set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
|
||||
" &
|
||||
|
||||
set --append pid_list (jobs --last --pid)
|
||||
end
|
||||
|
||||
wait $pid_list 2>/dev/null
|
||||
|
||||
for plugin in $fetch_plugins
|
||||
if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
|
||||
if set --local index (contains --index -- "$plugin" $install_plugins)
|
||||
set --erase install_plugins[$index]
|
||||
else
|
||||
set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
|
||||
end
|
||||
end
|
||||
end
|
||||
|
||||
for plugin in $update_plugins $remove_plugins
|
||||
if set --local index (contains --index -- "$plugin" $_fisher_plugins)
|
||||
set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
|
||||
|
||||
if contains -- "$plugin" $remove_plugins
|
||||
for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
|
||||
emit {$name}_uninstall
|
||||
end
|
||||
printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) " "$$plugin_files_var | string replace -- \~ ~
|
||||
set --erase _fisher_plugins[$index]
|
||||
end
|
||||
|
||||
command rm -rf (string replace -- \~ ~ $$plugin_files_var)
|
||||
|
||||
functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
|
||||
|
||||
for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
|
||||
complete --erase --command $name
|
||||
end
|
||||
|
||||
set --erase $plugin_files_var
|
||||
end
|
||||
end
|
||||
|
||||
if set --query update_plugins[1] || set --query install_plugins[1]
|
||||
command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
|
||||
end
|
||||
|
||||
for plugin in $update_plugins $install_plugins
|
||||
set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
|
||||
set --local files $source/{functions,themes,conf.d,completions}/*
|
||||
|
||||
if set --local index (contains --index -- $plugin $install_plugins)
|
||||
set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
|
||||
set --local conflict_files
|
||||
|
||||
for file in (string replace -- $source/ $fisher_path/ $files)
|
||||
contains -- $file $user_files && set --append conflict_files $file
|
||||
end
|
||||
|
||||
if set --query conflict_files[1] && set --erase install_plugins[$index]
|
||||
echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n" "$conflict_files >&2
|
||||
continue
|
||||
end
|
||||
end
|
||||
|
||||
for file in (string replace -- $source/ "" $files)
|
||||
command cp -RLf $source/$file $fisher_path/$file
|
||||
end
|
||||
|
||||
set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
|
||||
|
||||
set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
|
||||
|
||||
contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
|
||||
contains -- $plugin $install_plugins && set --local event install || set --local event update
|
||||
|
||||
printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) " "$$plugin_files_var | string replace -- \~ ~
|
||||
|
||||
for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
|
||||
source $file
|
||||
if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
|
||||
emit {$name}_$event
|
||||
end
|
||||
end
|
||||
end
|
||||
|
||||
command rm -rf $source_plugins
|
||||
|
||||
if set --query _fisher_plugins[1]
|
||||
set --local commit_plugins
|
||||
|
||||
for plugin in $file_plugins
|
||||
contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
|
||||
end
|
||||
|
||||
for plugin in $_fisher_plugins
|
||||
contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
|
||||
end
|
||||
|
||||
string replace --regex -- $HOME \~ $commit_plugins >$fish_plugins
|
||||
else
|
||||
set --erase _fisher_plugins
|
||||
command rm -f $fish_plugins
|
||||
end
|
||||
|
||||
set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
|
||||
|
||||
test "$total" != "0 0 0" && echo (string join ", " (
|
||||
test $total[1] = 0 || echo "Installed $total[1]") (
|
||||
test $total[2] = 0 || echo "Updated $total[2]") (
|
||||
test $total[3] = 0 || echo "Removed $total[3]")
|
||||
) plugin/s
|
||||
case \*
|
||||
echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
|
||||
end
|
||||
end
|
||||
|
||||
if ! set --query _fisher_upgraded_to_4_4
|
||||
set --universal _fisher_upgraded_to_4_4
|
||||
if functions --query _fisher_list
|
||||
set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
|
||||
command rm -rf $XDG_DATA_HOME/fisher
|
||||
functions --erase _fisher_{list,plugin_parse}
|
||||
fisher update >/dev/null 2>/dev/null
|
||||
else
|
||||
for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
|
||||
set $var (string replace -- ~ \~ $$var)
|
||||
end
|
||||
functions --erase _fisher_fish_postexec
|
||||
end
|
||||
end
|
@ -0,0 +1,33 @@
|
||||
set --local BASENAME --regex -- '[^/]+$'
|
||||
|
||||
@echo (fisher --version)
|
||||
|
||||
@test "fisher install" (
|
||||
fisher install tests/ponyo >/dev/null
|
||||
) "$ponyo" = "pyon pyon"
|
||||
|
||||
@test "fisher list" (
|
||||
fisher list | string match $BASENAME | string join " "
|
||||
) = "fisher fishtape ponyo"
|
||||
|
||||
@test "fisher list regex" (
|
||||
fisher list ponyo | string match $BASENAME
|
||||
) = ponyo
|
||||
|
||||
@test "pyon pyon" (fish --command ponyo | string join " ") = "pyon pyon ponyo"
|
||||
|
||||
@test "fisher update" (
|
||||
fisher update tests/ponyo >/dev/null
|
||||
) "$ponyo" = "pyon pyon pyon"
|
||||
|
||||
@test fish_plugins (
|
||||
string match --regex -- "[^/]+\$" <$__fish_config_dir/fish_plugins | string join " "
|
||||
) = "fisher fishtape ponyo"
|
||||
|
||||
@test "fisher remove" (
|
||||
fisher remove tests/ponyo >/dev/null
|
||||
) "$ponyo" = ""
|
||||
|
||||
@test "has state" -n (
|
||||
set --names | string match \*fisher\* | string collect
|
||||
)
|
@ -0,0 +1,13 @@
|
||||
echo pyon pyon
|
||||
|
||||
function ponyo_install --on-event ponyo_install
|
||||
set --global ponyo pyon pyon
|
||||
end
|
||||
|
||||
function ponyo_update --on-event ponyo_update
|
||||
set --global --append ponyo pyon
|
||||
end
|
||||
|
||||
function ponyo_uninstall --on-event ponyo_uninstall
|
||||
set --erase ponyo
|
||||
end
|
@ -0,0 +1,3 @@
|
||||
function ponyo
|
||||
echo ponyo
|
||||
end
|
Loading…
Reference in New Issue