4.4.4

By using the `-q` flag, we avoid issues from existing `.curlrc` settings, especially the `-O` option that sends output to disk instead of stdout. Since we use curl more as a plumbing tool than an interactive user command , ignoring `.curlrc` ensures consistent behavior across setups.

.github/workflows/ci.yml

@@ -1,20 +1,22 @@
 name: CI
 
 on: push
-       
+
 jobs:
   test:
     runs-on: ubuntu-latest
 
     steps:
-      - uses: actions/checkout@v2
+      - uses: actions/checkout@v3
       - name: Install Fish
         run: |
           sudo apt-add-repository -yn ppa:fish-shell/release-3
           sudo apt-get update
           sudo apt-get install -y fish
 
-      - name: Install Fisher
-        run: $GITHUB_WORKSPACE/ && source fisher.fish && fisher install .
+      - name: Install Tools
+        run: |
+          source $GITHUB_WORKSPACE/functions/fisher.fish
+          fisher install $GITHUB_WORKSPACE jorgebucaran/fishtape
+          fishtape tests/*.fish
         shell: fish {0}
-

README.md

@@ -1,63 +1,63 @@
 # Fisher
 
-> A plugin manager for [fish](https://fishshell.com)—the friendly interactive shell.
+> A plugin manager for [Fish](https://fishshell.com)—your friendly interactive shell. [Snag fresh plugins!](https://github.com/jorgebucaran/awsm.fish#readme)
 
-Manage functions, completions, bindings, and snippets from the command line. Extend your shell capabilities, change the look of your prompt and create repeatable configurations across different systems effortlessly.
+Take control of functions, completions, bindings, and snippets from the command line. Unleash your shell's true potential, perfect your prompt, and craft repeatable configurations across different systems effortlessly. Fisher's zero impact on shell startup keeps your shell zippy and responsive. No gimmicks, just smooth sailing!
 
-- [Oh My Fish](https://github.com/oh-my-fish/packages-main) plugin support.
-- Blazingly fast concurrent plugin downloads.
-- 100% pure fish—easy to contribute to or modify.
-- Zero configuration out of the box. Need to tweak a thing? [You can do that too](#using-your-fish_plugins-file).
+- Fisher is 100% pure-Fish, making it easy to contribute or modify
+- Scorching fast concurrent plugin downloads that'll make you question reality
+- Zero configuration needed—we're not kidding!
+- Oh My Fish! plugins supported too
 
-Looking for plugins? Browse [git.io/awesome.fish](https://git.io/awesome.fish) or [search](https://github.com/topics/fish-plugins) [on](https://github.com/topics/fish-package) [GitHub](https://github.com/topics/fish-plugin).
+> #### ☝️ [Upgrading from Fisher `3.x` or older? Strap in and read this!](https://github.com/jorgebucaran/fisher/issues/652)
 
 ## Installation
 
 ```console
-curl -sL git.io/fisher | source && fisher install jorgebucaran/fisher
+curl -sL https://raw.githubusercontent.com/jorgebucaran/fisher/main/functions/fisher.fish | source && fisher install jorgebucaran/fisher
 ```
 
 ## Quickstart
 
-You can install, update, and remove plugins interactively with Fisher, taking advantage of fish [tab completion](https://fishshell.com/docs/current/index.html#completion) and rich syntax highlighting.
+Fisher lets you install, update, and remove plugins like a boss. Revel in Fish's [tab completion](https://fishshell.com/docs/current/index.html#completion) and rich syntax highlighting while you're at it.
 
 ### Installing plugins
 
-Install plugins using the `install` command followed by the path to the repository on GitHub.
+To install plugins, use the `install` command and point it to the GitHub repository.
 
 ```console
-fisher install ilancosman/tide
+fisher install jorgebucaran/nvm.fish
 ```
 
-To get a specific version of a plugin add an `@` symbol after the plugin name followed by a tag, branch, or [commit](https://git-scm.com/docs/gitglossary#Documentation/gitglossary.txt-aiddefcommit-ishacommit-ishalsocommittish).
+> Wanna install from GitLab? No problemo—just prepend `gitlab.com/` to the plugin path.
+
+You can also snag a specific version of a plugin by adding an `@` symbol after the plugin name, followed by a tag, branch, or [commit](https://git-scm.com/docs/gitglossary#Documentation/gitglossary.txt-aiddefcommit-ishacommit-ishalsocommittish).
 
 ```console
-fisher install jorgebucaran/nvm.fish@1.1.0
+fisher install IlanCosman/tide@v5
 ```
 
-You can install plugins from a local directory too.
+And hey, you can install plugins from a local directory too!
 
 ```console
 fisher install ~/path/to/plugin
 ```
 
-> Fisher expands plugins into your fish configuration directory by default, overwriting existing files. If you wish to change this behavior, set `$fisher_path` to your preferred location and put it in your function path.
+> Heads up! Fisher expands plugins into your Fish configuration directory by default, overwriting existing files. If that's not your jam, set `$fisher_path` to your preferred location and put it in your function path ([#640](https://github.com/jorgebucaran/fisher/issues/640)).
 
 ### Listing plugins
 
-List all the plugins that are currently installed using the `list` command.
+Use the `list` command to see all your shiny installed plugins.
 
 ```console
 $ fisher list
 jorgebucaran/fisher
-ilancosman/tide
-jorgebucaran/nvm.fish@1.1.0
+ilancosman/tide@v5
+jorgebucaran/nvm.fish
 /home/jb/path/to/plugin
 ```
 
-> `jorgebucaran/fisher` is listed because we installed it to start with!
-
-The `list` command also accepts a regular expression to filter the output.
+The `list` command also plays nice with regular expressions for filtering the output.
 
 ```console
 $ fisher list \^/
@@ -66,23 +66,23 @@ $ fisher list \^/
 
 ### Updating plugins
 
-The `update` command updates one or more plugins to their latest version.
+`update` command to the rescue! It updates one or more plugins to their latest and greatest version.
 
 ```console
-fisher update ilancosman/tide
+fisher update jorgebucaran/fisher
 ```
 
-> `fisher update` by itself will update everything, including Fisher.
+> Just type `fisher update` to update everything in one fell swoop.
 
 ### Removing plugins
 
-Remove installed plugins using the `remove` command.
+Say goodbye to installed plugins with the `remove` command.
 
 ```console
-fisher remove jorgebucaran/nvm.fish@1.1.0
+fisher remove jorgebucaran/nvm.fish
 ```
 
-Someday you may want to remove everything, including Fisher.
+Feeling destructive? Wipe out everything, including Fisher itself.
 
 ```console
 fisher list | fisher remove
@@ -90,50 +90,104 @@ fisher list | fisher remove
 
 ## Using your `fish_plugins` file
 
-Whenever you install or remove a plugin from the command line, Fisher will write down all your installed plugins plugins to `$__fish_config_dir/fish_plugins`. Adding this file to your dotfiles or version control is the easiest way to share your configuration across different systems.
+Whenever you install or remove a plugin from the command line, Fisher jots down all the installed plugins in `$__fish_config_dir/fish_plugins`. Add this file to your dotfiles or version control to easily share your configuration across different systems.
 
-You can also edit this file and run `fisher update` to commit changes. Here's an example:
+You can also edit this file and run `fisher update` to commit changes like a pro:
 
 ```console
-nano $__fish_config_dir/fish_plugins
+$EDITOR $__fish_config_dir/fish_plugins
 ```
 
 ```diff
 jorgebucaran/fisher
-ilancosman/tide
-+ jethrokuan/z
-- jorgebucaran/nvm.fish@1.1.0
-/home/jb/path/to/plugin
+ilancosman/tide@v5
+jorgebucaran/nvm.fish
++ PatrickF1/fzf.fish
+- /home/jb/path/to/plugin
 ```
 
 ```console
 fisher update
 ```
 
-That will install **jethrokuan/z**, remove **jorgebucaran/nvm.fish**, and update everything else.
+This will install **PatrickF1**/**fzf.fish**, remove /**home**/**jb**/**path**/**to**/**plugin**, and update everything else.
+
+## Creating a plugin
+
+Plugins can include any number of files in `functions`, `conf.d`, and `completions` directories. Most plugins are just a single function or a [configuration snippet](https://fishshell.com/docs/current/index.html#configuration). Behold the anatomy of a typical plugin:
+
+<pre>
+<b>flipper</b>
+├── <b>completions</b>
+│   └── flipper.fish
+├── <b>conf.d</b>
+│   └── flipper.fish
+└── <b>functions</b>
+    └── flipper.fish
+</pre>
+
+Non `.fish` files and directories inside these locations will be copied to `$fisher_path` under `functions`, `conf.d`, or `completions` respectively.
 
-## Event system
+### Event system
 
-Fisher leverages the fish [event system](https://fishshell.com/docs/current/cmds/emit.html) to notify plugins when they are being installed, updated, or removed.
+Fish [events](https://fishshell.com/docs/current/cmds/emit.html) notify plugins when they're being installed, updated, or removed.
 
-> `--on-event` functions must be already loaded when their event is emitted. So put event handlers in your `conf.d` directory.
+> Keep in mind, `--on-event` functions must be loaded when their event is emitted. So, place your event handlers in the `conf.d` directory.
 
 ```fish
-# Defined in conf.d/foobar.fish
+# Defined in flipper/conf.d/flipper.fish
 
-function foobar_install --on-event foobar_install
-  # Set global variables, create bindings, and other install logic.
+function _flipper_install --on-event flipper_install
+    # Set universal variables, create bindings, and other initialization logic.
 end
 
-function foobar_update --on-event foobar_update
-  # Migrate resources, print warnings, and other update logic.
+function _flipper_update --on-event flipper_update
+    # Migrate resources, print warnings, and other update logic.
 end
 
-function foobar_uninstall --on-event foobar_uninstall
+function _flipper_uninstall --on-event flipper_uninstall
     # Erase "private" functions, variables, bindings, and other uninstall logic.
 end
 ```
 
+## Creating a theme
+
+A theme is like any other Fish plugin, but with a `.theme` file in the `themes` directory. Themes were introduced in [Fish `3.4`](https://github.com/fish-shell/fish-shell/releases/tag/3.4.0) and work with the `fish_config` builtin. A theme can also have files in `functions`, `conf.d`, or `completions` if necessary. Check out what a typical theme plugin looks like:
+
+<pre>
+<b>gills</b>
+├── <b>conf.d</b>
+│   └── gills.fish
+└── <b>themes</b>
+    └── gills.theme
+</pre>
+
+### Using `$fisher_path` with themes
+
+If you customize `$fisher_path` to use a directory other than `$__fish_config_dir`, your themes won't be available via `fish_config`. That's because Fish expects your themes to be in `$__fish_config_dir/themes`, not `$fisher_path/themes`. This isn't configurable in Fish yet, but there's [a request to add that feature](https://github.com/fish-shell/fish-shell/issues/9456).
+
+Fear not! You can easily solve this by symlinking Fisher's `themes` directory into your Fish config. First, backup any existing themes directory.
+
+```console
+mv $__fish_config_dir/themes $__fish_config_dir/themes.bak
+```
+
+Next, create a symlink for Fisher's themes directory.
+
+```console
+ln -s $fisher_path/themes $__fish_config_dir/themes
+```
+
+Want to use theme plugins and maintain your own local themes? You can do that too ([#708](https://github.com/jorgebucaran/fisher/issues/708)).
+
+## Discoverability
+
+While Fisher doesn't rely on a central plugin repository, discovering new plugins doesn't have to feel like navigating uncharted waters. To boost your plugin's visibility and make it easier for users to find, [add relevant topics to your repository](https://docs.github.com/en/repositories/managing-your-repositorys-settings-and-features/customizing-your-repository/classifying-your-repository-with-topics#adding-topics-to-your-repository) using [`fish-plugin`](https://github.com/topics/fish-plugin). By doing so, you're not only contributing to the Fisher community but also enabling users to explore new plugins and enhance their Fish shell experience. Don't let plugin discovery be a fishy business, tag your plugins today!
+
+## Acknowledgments
+
+Fisher started its journey in 2016 by [@jorgebucaran](https://github.com/jorgebucaran) as a shell configuration manager for Fish. Along the way, many helped shape it into what it is today. [Oh My Fish](https://github.com/oh-my-fish/oh-my-fish) paved the way as the first popular Fish framework. [@jethrokuan](https://github.com/jethrokuan) provided crucial support during the early years. [@PatrickF1](https://github.com/PatrickF1)'s candid feedback proved invaluable time and again. Bootstrapping Fisher was originally [@IlanCosman](https://github.com/IlanCosman)'s brilliant idea. Thank you to all our contributors! <3
+
 ## License
 
 [MIT](LICENSE.md)

completions/fisher.fish

@@ -1,7 +1,7 @@
-complete -c fisher -x -l help -d "print usage help"
-complete -c fisher -x -l version -d "print fisher version"
-complete -c fisher -x -n "__fish_use_subcommand" -a install -d "install plugins"
-complete -c fisher -x -n "__fish_use_subcommand" -a update -d "update installed plugins"
-complete -c fisher -x -n "__fish_use_subcommand" -a remove -d "remove installed plugins"
-complete -c fisher -x -n "__fish_use_subcommand" -a list -d "list installed plugins matching <regex>"
-complete -c fisher -x -n "__fish_seen_subcommand_from update remove" -a "(fisher list)"
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"

fisher.fish

@@ -1,204 +0,0 @@
-set -g fisher_version 4.1.0
-
-function fisher -a cmd -d "fish plugin manager"
-    set -q fisher_path || set -l fisher_path $__fish_config_dir
-    set -l fish_plugins $__fish_config_dir/fish_plugins
-
-    switch "$cmd"
-        case -v --version
-            echo "fisher, version $fisher_version"
-        case "" -h --help
-            echo "usage: fisher install <plugins...>  install plugins"
-            echo "       fisher remove  <plugins...>  remove installed plugins"
-            echo "       fisher update  <plugins...>  update installed plugins"
-            echo "       fisher update                update all installed plugins"
-            echo "       fisher list    [<regex>]     list installed plugins matching regex"
-            echo "options:"
-            echo "       -v or --version  print fisher version"
-            echo "       -h or --help     print this help message"
-        case ls list
-            string match --entire --regex -- "$argv[2]" $_fisher_plugins
-        case install update remove rm
-            isatty || read -laz stdin && set argv $argv[2..-1] $stdin
-            set -l install_plugins
-            set -l update_plugins
-            set -l remove_plugins
-            set -l arg_plugins $argv
-            set -l old_plugins $_fisher_plugins
-            set -l new_plugins
-
-            if test -z "$argv[1]"
-                if test "$cmd" != update || test ! -e $fish_plugins
-                    echo "fisher: not enough arguments for command: \"$cmd\"" >&2 && return 1
-                end
-                set arg_plugins (string trim <$fish_plugins)
-            end
-
-            for plugin in $arg_plugins
-                test -e "$plugin" && set plugin (realpath $plugin)
-                contains -- "$plugin" $new_plugins || set -a new_plugins $plugin
-            end
-
-            if set -q argv[1]
-                for plugin in $new_plugins
-                    if contains -- "$plugin" $old_plugins
-                        if test "$cmd" = install || test "$cmd" = update
-                            set -a update_plugins $plugin
-                        else
-                            set -a remove_plugins $plugin
-                        end
-                    else if test "$cmd" != install
-                        echo "fisher: plugin not installed: \"$plugin\"" >&2 && return 1
-                    else
-                        set -a install_plugins $plugin
-                    end
-                end
-            else
-                for plugin in $new_plugins
-                    if contains -- "$plugin" $old_plugins
-                        set -a update_plugins $plugin
-                    else
-                        set -a install_plugins $plugin
-                    end
-                end
-
-                for plugin in $old_plugins
-                    if not contains -- "$plugin" $new_plugins
-                        set -a remove_plugins $plugin
-                    end
-                end
-            end
-
-            set -l pid_list
-            set -l source_plugins
-            set -l fetch_plugins $update_plugins $install_plugins
-
-            for plugin in $fetch_plugins
-                set -l source (command mktemp -d)
-                set -a source_plugins $source
-
-                command mkdir -p $source/{completions,conf.d,functions}
-
-                fish -c "
-                if test -e $plugin
-                    command cp -Rf $plugin/* $source
-                else 
-                    set temp (command mktemp -d)
-                    set name (string split \@ $plugin) || set name[2] HEAD
-                    set url https://codeload.github.com/\$name[1]/tar.gz/\$name[2]
-                    set -q fisher_user_api_token && set opts -u $fisher_user_api_token
-
-                    echo fetching \$url >&2
-                    if command curl $opts -Ss -w \"\" \$url 2>&1 | command tar -xzf- -C \$temp 2>/dev/null
-                        command cp -Rf \$temp/*/* $source
-                    else
-                        echo fisher: invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
-                        command rm -rf $source
-                    end
-                    command rm -rf \$temp
-                end
-
-                test ! -e $source && exit
-                command mv -f (string match --entire --regex -- \.fish\\\$ $source/*) $source/functions 2>/dev/null" &
-
-                set -a pid_list $last_pid
-            end
-
-            wait $pid_list 2>/dev/null
-
-            for plugin in $fetch_plugins
-                if set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
-                    if set -l index (contains --index -- "$plugin" $install_plugins)
-                        set -e install_plugins[$index]
-                    else
-                        set -e update_plugins[(contains --index -- "$plugin" $update_plugins)]
-                    end
-                end
-            end
-
-            for plugin in $update_plugins $remove_plugins
-                if set --erase _fisher_plugins[(contains --index -- $plugin $_fisher_plugins)] 2>/dev/null
-                    set -l plugin_files_var _fisher_(string escape --style=var $plugin)_files
-
-                    if contains -- "$plugin" $remove_plugins
-                        for file in (string match --entire --regex -- "conf\.d/" $$plugin_files_var)
-                            emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_uninstall
-                        end
-                        echo -s (set_color --bold)"removing $plugin"(set_color normal) \n-$$plugin_files_var >&2
-                    end
-
-                    command rm -rf $$plugin_files_var
-                    functions --erase (string match --entire --regex -- "functions/" $$plugin_files_var \
-                        | string replace --all --regex -- '^.*/|\.fish$' "")
-                    set --erase $plugin_files_var
-                end
-            end
-
-            for plugin in $update_plugins $install_plugins
-                set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
-
-                command cp -Rf $source/{functions,conf.d,completions} $fisher_path
-
-                set -l files (string replace $source $fisher_path $source/{functions,conf.d,completions}/*)
-                set -U _fisher_(string escape --style=var $plugin)_files $files
-
-                contains -- $plugin $_fisher_plugins || set -Ua _fisher_plugins $plugin
-                contains -- $plugin $install_plugins && set -l event "install" || set -l event "update"
-
-                echo -s (set_color --bold)"installing $plugin"(set_color normal) \n+$files >&2
-
-                for file in (string match --entire --regex -- "[functions/|conf\.d/].*fish\$" $files)
-                    source $file
-                    if string match --quiet --regex -- "conf\.d/" $file
-                        emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_$event
-                    end
-                end
-            end
-
-            command rm -rf $source_plugins
-            functions -q fish_prompt || source $__fish_data_dir/functions/fish_prompt.fish
-
-            set -q _fisher_plugins[1] || set -e _fisher_plugins
-            set -q _fisher_plugins && printf "%s\n" $_fisher_plugins >$fish_plugins || command rm -f $fish_plugins
-
-            set -l total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
-            test "$total" != "0 0 0" && echo (string join ", " (
-                test $total[1] = 0 || echo "$total[1] installed") (
-                test $total[2] = 0 || echo "$total[2] updated") (
-                test $total[3] = 0 || echo "$total[3] removed")
-            ) "plugin/s" >&2
-        case \*
-            echo "fisher: unknown flag or command: \"$cmd\" (see `fisher -h`)" >&2 && return 1
-    end
-end
-
-## Migrations ##
-set -q XDG_DATA_HOME || set -l XDG_DATA_HOME ~/.local/share
-test -e $XDG_DATA_HOME/fisher && command rm -rf $XDG_DATA_HOME/fisher
-if functions -q _fisher_self_update || test -e $__fish_config_dir/fishfile
-    function _fisher_migrate
-        function _fisher_complete
-            if not _fisher_list | string match --entire --regex --quiet -- jorgebucaran/fisher
-                fisher install jorgebucaran/fisher 2>/dev/null
-            end
-            functions --erase _fisher_complete
-        end
-        set -q XDG_DATA_HOME || set XDG_DATA_HOME ~/.local/share
-        set -q XDG_CACHE_HOME || set XDG_CACHE_HOME ~/.cache
-        set -q XDG_CONFIG_HOME || set XDG_CONFIG_HOME ~/.config
-        set -q fisher_path || set fisher_path $__fish_config_dir
-
-        if test -e $__fish_config_dir/fishfile
-            command awk '/#|^gitlab|^ *$/ { next } $0' <$__fish_config_dir/fishfile >>$__fish_config_dir/fish_plugins
-        end
-
-        command rm -rf $__fish_config_dir/fishfile $fisher_path/{conf.d,completions}/fisher.fish {$XDG_DATA_HOME,$XDG_CACHE_HOME,$XDG_CONFIG_HOME}/fisher
-        functions --erase _fisher_migrate _fisher_copy_user_key_bindings _fisher_ls _fisher_fmt _fisher_self_update _fisher_self_uninstall _fisher_commit _fisher_parse _fisher_fetch _fisher_add _fisher_rm _fisher_jobs _fisher_now _fisher_help
-
-        fisher update
-    end
-
-    echo "bootstrapping fisher $fisher_version for the first time, learn more at "(set_color --bold --underline)"https://git.io/fisher-4"(set_color normal) >&2
-
-    _fisher_migrate
-end

functions/fisher.fish

@@ -0,0 +1,240 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.4.4
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install <plugins...>  Install plugins"
+            echo "       fisher remove  <plugins...>  Remove installed plugins"
+            echo "       fisher update  <plugins...>  Update installed plugins"
+            echo "       fisher update                Update all installed plugins"
+            echo "       fisher list    [<regex>]     List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v, --version  Print version"
+            echo "       -h, --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins)
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if ! set --query file_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins $file_plugins
+            end
+
+            for plugin in $arg_plugins
+                set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            set --local fish_path (status fish-path)
+
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,themes,functions}
+
+                $fish_path --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set temp (command mktemp -d)
+                        set repo (string split -- \@ $plugin) || set repo[2] HEAD
+
+                        if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
+                            set name (string split -- / \$path)[-1]
+                            set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
+                        else
+                            set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
+                        end
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        if command curl -q --silent -L \$url | command tar -xzC \$temp -f - 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var | string replace -- \~ ~
+                        set --erase _fisher_plugins[$index]
+                    end
+
+                    command rm -rf (string replace -- \~ ~ $$plugin_files_var)
+
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,themes,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -RLf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var | string replace -- \~ ~
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            if set --query _fisher_plugins[1]
+                set --local commit_plugins
+
+                for plugin in $file_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
+                end
+
+                for plugin in $_fisher_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
+                end
+
+                printf "%s\n" $commit_plugins >$fish_plugins
+            else
+                set --erase _fisher_plugins
+                command rm -f $fish_plugins
+            end
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+if ! set --query _fisher_upgraded_to_4_4
+    set --universal _fisher_upgraded_to_4_4
+    if functions --query _fisher_list
+        set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
+        command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_{list,plugin_parse}
+        fisher update >/dev/null 2>/dev/null
+    else
+        for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
+            set $var (string replace -- ~ \~ $$var)
+        end
+        functions --erase _fisher_fish_postexec
+    end
+end

tests/fisher.fish

@@ -0,0 +1,33 @@
+set --local BASENAME --regex -- '[^/]+$'
+
+@echo (fisher --version)
+
+@test "fisher install" (
+    fisher install tests/ponyo >/dev/null 
+) "$ponyo" = "pyon pyon"
+
+@test "fisher list" (
+    fisher list | string match $BASENAME | string join " "
+) = "fisher fishtape ponyo"
+
+@test "fisher list regex" (
+    fisher list ponyo | string match $BASENAME
+) = ponyo
+
+@test "pyon pyon" (fish --command ponyo | string join " ") = "pyon pyon ponyo"
+
+@test "fisher update" (
+    fisher update tests/ponyo >/dev/null
+) "$ponyo" = "pyon pyon pyon"
+
+@test "fisher remove" (
+    fisher remove tests/ponyo >/dev/null
+) "$ponyo" = ""
+
+@test "has state" -n (
+    set --names | string match \*fisher\* | string collect
+)
+
+@test fish_plugins (
+    fisher list | string collect
+) = (read --null <$__fish_config_dir/fish_plugins | string collect)

tests/ponyo/conf.d/ponyo.fish

@@ -0,0 +1,13 @@
+echo pyon pyon
+
+function ponyo_install --on-event ponyo_install
+    set --global ponyo pyon pyon
+end
+
+function ponyo_update --on-event ponyo_update
+    set --global --append ponyo pyon
+end
+
+function ponyo_uninstall --on-event ponyo_uninstall
+    set --erase ponyo
+end

tests/ponyo/functions/ponyo.fish

@@ -0,0 +1,3 @@
+function ponyo
+    echo ponyo
+end