mirror of
https://github.com/oxen-io/lokinet.git
synced 2024-11-17 15:25:35 +00:00
c5faa86926
Refactors many things in cmake to improve and simplify:
- don't use variable indirection for target names; target names are
*already* a variable of sorts. (e.g. ${UTIL_LIB} is now just
lokinet-util). cmake/basic_definitions.cmake is now gone.
- fix LTO enabling to use the standard cmake (3.9+) LTO mechanism rather
than shoving a bunch of flag hacks through link_libraries and
add_compile_options. This also now enables LTO when building a shared
library (because previously the -flto hacks were only turned on in the
static code for some reason).
- build liblokinet as *either* shared library or static library, but not
both. Building both makes things more complicated because they had
different names (lokinet-shared or lokinet-static) and seems pointless:
you generally want one or the other. Now there is just the liblokinet
target, which will be shared or static depending on the value of
BUILD_SHARED_LIBS.
- Simplify lokinet-cryptography AVX2 code: just build *one* library, and
add in the additional AVX2 files when possible, rather than building two
and needing to merge them.
- Compress STATIC_LINK and STATIC_LINK_RUNTIME into just STATIC_LINK.
It makes no sense to use one of these (_RUNTIME) on Windows and the
other on non-Windows when they appear to try to do the same thing.
- remove a bunch of annotations from `endif(FOO)` -> `endif()`.
- move all the tuntap compilation code (including OS-specific source
file selection) into vendor/CMakeLists.txt and build tuntap as an
intermediate OBJECT library rather than keeping a global variable in 5
different files.
- move release motto define to root cmake; it made no sense being
duplicated in both unix.cmake and win32.cmake
- fix add_log_tag to not stomp on any existing source compile flags with
its definition. Also use proper compile definition property instead of
cramming it into compile flags.
- make optimization/linker flags less hacky. There's no reason for us
to force particular optimization flags because the cmake build type
already does that (e.g. -DCMAKE_BUILD_TYPE=Release does -O3). Not doing
that also silences a bunch of cmake warnings because it thinks "-O0 -g3"
etc. are link libraries (which is reasonable: that's what the code was
telling cmake they are).
- sets the default build type to RelWithDebInfo which gives us `-O2 -g`
if you don't specify a build type.
- Move PIC up (so that the things loaded in unix.cmake, notably libuv,
have it set).
- Add a custom `curl` interface library that carries the correct link
target and include paths for curl (system or bundled).
44 lines
1.6 KiB
CMake
44 lines
1.6 KiB
CMake
|
|
if(SHADOW)
|
|
add_shadow_plugin(shadow-plugin main.cpp ${TRACY_ROOT}/TracyClient.cpp)
|
|
target_link_libraries(shadow-plugin liblokinet)
|
|
enable_lto(shadow-plugin)
|
|
else()
|
|
add_executable(lokinet main.cpp)
|
|
add_executable(lokinetctl lokinetctl.cpp)
|
|
enable_lto(lokinet lokinetctl)
|
|
|
|
if(TRACY_ROOT)
|
|
target_sources(lokinet PRIVATE ${TRACY_ROOT}/TracyClient.cpp)
|
|
endif()
|
|
|
|
foreach(exe lokinet lokinetctl)
|
|
if(WIN32 AND NOT MSVC_VERSION)
|
|
target_sources(${exe} PRIVATE ../llarp/win32/version.rc)
|
|
target_link_libraries(${exe} PRIVATE ws2_32 iphlpapi)
|
|
elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
|
|
target_link_directories(${exe} PRIVATE /usr/local/lib)
|
|
endif()
|
|
target_link_libraries(${exe} PRIVATE liblokinet)
|
|
target_compile_definitions(${exe} PRIVATE -DVERSIONTAG=${GIT_VERSION_REAL})
|
|
add_log_tag(${exe})
|
|
endforeach()
|
|
|
|
install(TARGETS lokinet RUNTIME DESTINATION bin COMPONENT lokinet)
|
|
if(WIN32)
|
|
install(PROGRAMS ${CMAKE_SOURCE_DIR}/lokinet-bootstrap.ps1 DESTINATION bin COMPONENT lokinet)
|
|
else()
|
|
install(PROGRAMS ${CMAKE_SOURCE_DIR}/lokinet-bootstrap DESTINATION bin COMPONENT lokinet)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "Linux")
|
|
install(CODE "execute_process(COMMAND setcap cap_net_admin,cap_net_bind_service=+eip ${CMAKE_INSTALL_PREFIX}/bin/lokinet)")
|
|
endif()
|
|
|
|
if(CURL_FOUND)
|
|
target_include_directories(lokinetctl PRIVATE ${CURL_INCLUDE_DIRS})
|
|
target_link_libraries(lokinetctl PRIVATE ${CURL_LIBRARIES})
|
|
endif(CURL_FOUND)
|
|
|
|
endif()
|